*==============================================================================
* Function: NaturalSort
* Purpose: Sorts an array in natural rather than ASCII order
* Author: Doug Hennig
* Last Revision: 12/13/2007
* Parameters: taArray - the array to sort (passed by reference)
* tnColumn - the column to sort on (optional: if it isn't
* specified, column 1 is used)
* tlDescending - .T. to sort in descending order; if .F. or
* not specified, ascending order is used
* Returns: .T. if it succeeded or .F. (and an error is raised) if
* invalid parameters are passed or the specified column
* doesn't contain a homogeneous data type
* Environment in: none
* Environment out: none
*==============================================================================
lparameters taArray, ;
tnColumn, ;
tlDescending
local lnColumn, ;
lnRows, ;
lnCols, ;
lnOrder, ;
laArray[1], ;
lnI, ;
lcKey, ;
llInNumeric, ;
lcString, ;
lnJ, ;
lcChar, ;
llNumeric, ;
lcNumeric, ;
laClone[1], ;
lnIndex
* Define some constants.
#define cnLENGTH 20
&& the length to pad numeric sections to
#define cnERR_ARGUMENT_INVALID 11
&& Function argument value, type, or count is invalid
#define cnERR_DATA_TYPE_MISMATCH 9
&& Data type mismatch
* Ensure taArray is an array and tlDescending is logical if it's specified.
if type('taArray', 1) <> 'A' or ;
(pcount() = 3 and vartype(tlDescending) <> 'L')
error cnERR_ARGUMENT_INVALID
return .F.
endif type('taArray', 1) <> 'A' ...
* If the column to sort on wasn't specified, assume 1.
lnColumn = iif(pcount() = 2, tnColumn, 1)
* Figure out the size of the source array.
lnRows = alen(taArray, 1)
lnCols = alen(taArray, 2)
* Ensure the column to sort on is valid.
if vartype(lnColumn) <> 'N' or not between(lnColumn, 1, max(lnCols, 1))
error cnERR_ARGUMENT_INVALID
return .F.
endif vartype(lnColumn) <> 'N' ...
* Figure out the order flag for ASORT().
lnOrder = iif(tlDescending, 1, 0)
* Get the data type of the first key value. If it isn't character, we don't
* have to do anything fancy; ASORT() will take care of it for us.
if vartype(taArray[1, lnColumn]) = 'C'
* Create an array we'll sort on.
dimension laArray[lnRows, 2]
* Go through each element we're sorting on.
for lnI = 1 to lnRows
lcKey = taArray[lnI, lnColumn]
* Bug out if the data type is different.
if vartype(lcKey) <> 'C'
error cnERR_DATA_TYPE_MISMATCH
return .F.
endif vartype(lcKey) <> 'C'
* Create a key that will sort properly by looking for numeric sections and
* left-padding them with zeros.
llInNumeric = .F.
lcString = ''
for lnJ = 1 to len(lcKey)
lcChar = substr(lcKey, lnJ, 1)
llNumeric = isdigit(lcChar) or ;
(lcChar = '.' and isdigit(substr(lcKey, lnJ + 1, 1)))
do case
case llNumeric and llInNumeric
&& if we have a digit and we're already in a numeric
&& section, add to the numeric part
lcNumeric = lcNumeric + lcChar
case llNumeric
&& if we have a digit and we're not in a numeric
&& section, flag that we are in such a section and add to
&& the numeric part
llInNumeric = .T.
lcNumeric = lcChar
case llInNumeric
&& we don't have a digit and we were in a numeric section
&& so pad the section and add it to our string
llInNumeric = .F.
lcString = lcString + padl(lcNumeric, cnLENGTH, '0') + ;
lcChar
otherwise
lcString = lcString + lcChar
endcase
next lnJ
* Finish the string if we were still processing a numeric section.
if llInNumeric
lcString = lcString + padl(lcNumeric, cnLENGTH, '0')
endif llInNumeric
* Store the new key and the original index in our sort array.
laArray[lnI, 1] = lcString
laArray[lnI, 2] = lnI
next lnI
* Now sort the array and reorder the values in the source array by cloning it
* and copying the values from the each row in the clone to the new row in the
* source array.
asort(laArray, 1, -1, lnOrder, 1)
acopy(taArray, laClone)
for lnI = 1 to lnRows
lnIndex = laArray[lnI, 2]
if lnCols > 0
for lnJ = 1 to lnCols
taArray[lnI, lnJ] = laClone[lnIndex, lnJ]
next lnJ
else
taArray[lnI] = laClone[lnIndex]
endif lnCols > 0
next lnI
* Just use ASORT to do the job.
else
asort(taArray, lnColumn, -1, lnOrder, 0)
endif vartype(taArray[1, lnColumn]) = 'C'
return .T.
[Dirs]This gives all users the ability to write to the folder.
Name: "{app}\Data"; Permissions: everyone-modify
ltBlank = iif(vartype(ttBlank) $ 'TD', ttBlank, SQL_SERVER_EMPTY_DATE_Y2K)and add the following statement after the LOCAL statement:
#include Include\AllDefs.HSecond, JimExport (interesting method name!) in WizUsz.PRG also used a hard-coded value, so change the assignment to lcEmptyDateValue in the first CASE statement to:
lcEmptyDateValue = "IIF(EMPTY(" + ALLT(lcCursorName)+'.'+ALLT(aTblFields[ii,1])+ "), " + ;
transform(This.BlankDateValue) + ","Finally, to change the actual date, change these two constants in AllDefs.H to the desired values:#DEFINE SQL_SERVER_EMPTY_DATE_Y2K {^1900-01-01}
#DEFINE SQL_SERVER_EMPTY_DATE_CHAR "01/01/1900"Rebuild UpsizingWizard.APP and you're ready to go.
Rick went on to thank other people who helped us, including Bob Kocher (who previously ran the conference and graciously helped us with ideas and suppliers), Dave Aring (who created the logos and Kokopelli application), Mike and Toni Feltman (for their VFE offer to all attendees), other conference organizers (Whil Hentzen, Rainer Becker, Kevin Cully, Igor Vit, and others), DBI (for creating the conference CDs), Craig Boyd (who hosts http://www.swfox.net/), bloggers and podcasters (who helped get the word out), speakers (who were all introduced by name), Andy Kramek and Marcia Akins (for creating a "how to speak good" video), Southwest Fox staff (Marshal and Therese), and our sponsors.
Tamar went over conference logistics: what's in the binder, where the session rooms are, using Kokopelli, where meals are, and so on. I then discussed the trade show, going over the hours and urging attendees to visit the booths and talk to the vendors about their wares, and the two developer meeting at the conference, once for Visual MaxFrame Professional and one for Stonefield Query.
Rick spent a few minutes discussing VFP 9 SP2, including what's in it and the fact that there are two releases of it (which he called SP2 and SP2A for fun). He then talked about Sedna: what it is, what components are in it, and when it may be released.
I then had the honor of announcing the recipient of the 2007 FoxPro Community Lifetime Achievement Award. During all of the conference planning, Rick and I told Tamar that the award was for someone else. I did up PowerPoint slides with that person's biography, Rick (who designed the physical award) created a design with that person's name, and we even practiced the keynote earlier that day with the other person as the recipient. So, when I announced that Tamar was the recipient, she jumped liked she'd touched a 20,000 volt power line. I went over the things Tamar has done in her career and why she so rightly deserved the award. I was especially pleased that her husband Marshal could be in the room to watch the announcement. Rick presented her with the award and then, to my surprise, also presented awards to the previous recipients--Whil Hentzen, Rick Strahl, and I--who hadn't actually received anything physical before. It was great that all of the recipients were actually at the conference.
While Christof Wollenhaupt was setting up for the next part of the keynote, we did some drawings for raffle prizes, including several Hentzenwerke books. Christof then amazed the audience with his demo of Guineu, a .NET runtime for VFP applications. He started by telling is that FoxPro was dead and it was really a shame that you can't run VFP applications on Windows Mobile devices while he proceded to do exactly that. He then showed the same VFP app running as a .NET WinForm application and a browser application, all the while saying it was too bad that it wasn't possible to do that. It was a great presentation that really fired up the crowd!
We gave our some more prizes while Toni Feltman set up for her presentation on .NET Extender for VFP and VFP Compiler for .NET from eTecnologia.net. Although it has a similar purpose as Guineu (running VFP applications in .NET), it has a completely different technology. Toni demoed some of the current capabilities of these products and mentioned that there are new releases every month with additional features added. She also suggested that at just $120, it was worth buying just to see where it's going to go.
We gave away a few more prizes while Craig Boyd and Alan Stevens prepared to show their "super secret project". They're using extensibility in Visual Studio to create something they call VFP Studio, which gives Visual Studio the ability to compile and generate VFP DLLs when you build a .NET solution. This saves jumping back and forth between different IDEs.
I then wound up the keynote with a call to action: download SP2 and Sedna, join VFPX, start your own blog, join (or start, as Cathy Pountney pointed out) a user group, and tell the world about VFP.
We then adjourned to the courtyard and trade show area for a welcome reception. It was supposed to only last until 9:30 but attendees were still talking to vendors as late as 10:30, and it appeared that everyone had a great time.
Whew! Thursday was a great kickoff for Southwest Fox!
As Kevin Cully notes, the deadline for registration for FoxForward 2007 is also approaching.
You owe it to yourself and your career as a development professional to attend one of these conferences, or the German DevCon, another great conference now in its 13th year.
So, I've been reworking those parts of Stonefield Query that expected to write to the current or application folder. It was actually fairly easy to do because most file paths were referenced with an application object property (e.g. USE (oApp.cAppDataDir) + "SomeTable") so simply changing the value of the property redirected the files to a location the user has write access to. I then ran the application and looked for any files that appeared in my virtualization folder, and turned off virtualization and tested to see if anything broke. I found a few stragglers where I hadn't put a path on the filename (typically writing to some temporary files) and fixed them.
However, one thing puzzled me: a table that wasn't being written to was virtualized. In tracking it down, I found that the virtualized table was created immediately after the USE command. To make matters even odder, when I turn off virtualization, the table wasn't virtualized and the application didn't give an error. Also, while the DBF and FPT files were virtualized, the CDX was not.
I guess this makes sense. Since I was opening the table in read-write mode (ie. no NOUPDATE clause), I suspect VFP was doing some minor update to the table behind the scenes (e.g. writing to the header of DBF and FPT files for locking purposes), resulting in it being virtualized. You can see this effect if you open one of the classes in the FFC subdirectory of the VFP home directory; simply opening it immediately causes its virtualization. With virtualization turned off, the table was automatically read-only since it's in a protected folder, so there's no need to virtualize it. Adding a NOUPDATE clause to the table (since it's a meta data table, it's used for reference purposes only) took care of that.
However, the SDK for Stonefield Query includes an editor program for that table, so that program does open the table for read-write purposes and will likely write to the table (otherwise it wouldn't be an editor). The problem is that the user may be unaware that the table is virtualized and will likely distribute the wrong instance of the table (the one in the application folder rather than the virtualized one) after making changes to it. So, I figured I should let them know which table they're writing to so they know which one to distribute.
However, how can you tell if a file has been virtualized? If you open a file in C:\Program Files\Some Folder and that file has been virtualized, the operating system actually opens the virtualized copy instead of the one you specified, and the application can't tell the difference.
I settled on the obvious solution: check whether a virtualized copy of the file in question exists. If so, we know that's the one Vista will open. Here's some code to do that. First, we get the directory the application is running in (not necessarily the current directory) by calling GetAppDirectory (a routine I wrote years ago; I'll show you the code later). Then we call SpecialFolders, a routine I discussed in my Finding the Paths for Special Folders blog entry, to get the current user's local app data path (C:\Users\user name\AppData\Local\). Notice that this code uses SUBSTR(lcDirectory, 3) to strip the drive letter, colon, and backslash from the application folder name. We then check if the desired file exists in the virtualization folder.
lcDirectory = GetAppDirectory()
lcVirtualPath = SpecialFolders('LocalAppData') + ;
'VirtualStore\' + substr(lcDirectory, 3)
lcFile = lcVirtualPath + 'SomeTable.DBF'
if file(lcFile)
* the table has been virtualized
endif
Here's the code for GetAppDirectory. It handles runtime and development time conditions differently.
local lcPath
if version(2) = 2
lcPath = justpath(sys(16, 0))
if atc('PROCEDURE', lcPath) > 0
lcPath = substr(lcPath, rat(':', lcPath) - 1)
endif atc('PROCEDURE', lcPath) > 0
else
lcPath = addbs(justpath(_vfp.ServerName))
endif version(2) = 2
return lcPath
<captions>We want to use this XML to update the Stonefield Query data dictionary. Our first attempt used XMLTOCURSOR() to put the XML into a cursor, which we then process. It took somewhere around 30 seconds, which seems like forever because it happens every time the user starts Stonefield Query. XMLTOCURSOR() uses the XML DOM object, which gets exponentially slower as the XML gets larger.
<newrecord>
<tablename>SomeTableName</tablename>
<fieldname>SomeFieldName</fieldname>
<fieldcaption>Caption for Field</fieldcaption>
</newrecord>
...
</captions>
create cursor __CAPTIONS (FIELDNAME C(119), CAPTION C(60))Interestingly, this turned out to be way slower than XMLTOCURSOR() (in fact, I stopped it after a couple of minutes, so I don't know how long it would've taken).
for lnI = 1 to occurs('<tablename>', lcXML)
lcTable = strextract(lcXML, '<tablename>', '</tablename>', lnI)
lcField = strextract(lcXML, '<fieldname>', '</fieldname>', lnI)
lcCaption = strextract(lcXML, '<fieldcaption>', '</fieldcaption>', lnI)
insert into __CAPTIONS values (lcTable + '.' + lcField, lcCaption)
next lnI
#define ccCRLF chr(13) + chr(10)This took 0.7 seconds, 42 times faster than using XMLTOCURSOR().
lcXML = strtran(lcXML, '<tablename>')
lcXML = strtran(lcXML, '</tablename>' + ccCRLF + '<fieldname>', '.')
lcXML = strtran(lcXML, '</fieldname>' + ccCRLF + '<fieldcaption>', ',"')
lcXML = strtran(lcXML, '</fieldcaption>' + ccCRLF + '</newrecord>' + ;
ccCRLF + '<newrecord>', '"')
lcXML = strtran(lcXML, '</fieldcaption>' + ccCRLF + '</newrecord>' + ;
ccCRLF + '</vfpdata>', '"')
lcTemp = forcepath(sys(2015) + '.txt', sys(2023))
strtofile(substr(lcXML, 91), lcTemp)
create cursor __CAPTIONS (FIELDNAME C(119), CAPTION C(60))
append from (lcTemp) delimited
erase (lcTemp)
create cursor __CAPTIONS (FIELDNAME C(119), CAPTION C(60))This took 0.4 seconds. Wow! Nearly two orders of magnitude improvement over the initial attempt. It really does pay to take out the slow parts!
lnLines = alines(laLines, lcXML)
for lnI = 1 to lnLines
lcLine = laLines[lnI]
do case
case '<TableName>' $ lcLine
lcTable = strextract(lcLine, '<TableName>', '</TableName>')
case '<FieldName>' $ lcLine
lcField = strextract(lcLine, '<FieldName>', '</FieldName>')
case '<FieldCaption>' $ lcLine
lcCaption = strextract(lcLine, '<FieldCaption>', '</FieldCaption>')
insert into __CAPTIONS values (lcTable + '.' + lcField, lcCaption)
endcase
next lnI
lcSystem = Thisform.oUtility.GetSystemDirectory()(GetSystemDirectory is a utility method that returns the location of the Windows System folder; I'll show the code for that later.)
try
run /n1 &lcSystem..odbcad32.exe
catch
endtry
lcSystem = oUtility.GetSystemDirectory()(Like GetSystemDirectory, ShellExecute is another utility function. It runs the specified command. The cool thing about ShellExecute is that it'll launch the appropriate program. In the case of an EXE, it runs it. In the case of an HTML file, it launches the default browser. In the case of a DOC file, it launches Word.)
try
oUtility.ShellExecute(lcSystem + 'odbcad32.exe', 'RunAs')
catch
endtry
#define cnMAX_PATH 260Here's the code for ShellExecute:
#define ccNULL chr(0)
local lcBuffer
lcBuffer = space(cnMAX_PATH)
declare integer GetSystemDirectory in Win32API ;
string @szBuffer, integer nLength
GetSystemDirectory(@lcBuffer, cnMAX_PATH)
return addbs(alltrim(left(lcBuffer, at(ccNULL, lcBuffer) - 1)))
lparameters tcFileName, ;
tcOperation, ;
tcWorkDir, ;
tcParameters
local lcFileName, ;
lcWorkDir, ;
lcOperation, ;
lcParameters, ;
lnShow
if empty(tcFileName)
return -1
endif empty(tcFileName)
lcFileName = alltrim(tcFileName)
lcWorkDir = iif(vartype(tcWorkDir) = 'C', alltrim(tcWorkDir), '')
lcOperation = iif(vartype(tcOperation) = 'C' and not empty(tcOperation), ;
alltrim(tcOperation), 'Open')
lcParameters = iif(vartype(tcParameters) = 'C', alltrim(tcParameters), '')
lnShow = iif(upper(lcOperation) = 'Print', 0, 1)
declare integer ShellExecute in SHELL32.DLL ;
integer nWinHandle, ; && handle of parent window
string cOperation, ; && operation to perform
string cFileName, ; && filename
string cParameters, ; && parameters for the executable
string cDirectory, ; && default directory
integer nShowWindow && window state
return ShellExecute(0, lcOperation, lcFilename, lcParameters, lcWorkDir, ;
lnShow)
* Create a task that runs at 3:00 AM every day.
loSchedule = createobject('VistaTaskScheduler')
with loSchedule
.TaskName = 'My Task Name'
.UserName = 'Your Windows UserName'
.Password = 'Your Windows Password'
.StartTime = {^2007-04-26 03:00:00}
.EXEName = 'Full path to EXE'
.EXEParameters = 'Any parameters to pass'
.ScheduleType = 1 && daily
if not .CreateTask()
messagebox(.ErrorMessage)
endif not .CreateTask()
endwith
* Create a weekly task that runs at 3:00 AM Tues, Thurs, and Sat
* of every second week.
loSchedule = createobject('VistaTaskScheduler')
with loSchedule
.TaskName = 'My Task Name'
.UserName = 'Your Windows UserName'
.Password = 'Your Windows Password'
.StartTime = {^2007-04-26 03:00:00}
.EXEName = 'Full path to EXE'
.EXEParameters = 'Any parameters to pass'
.ScheduleType = 2 && weekly
.Interval = 2
store .T. to .DaysOfWeek[3], .DaysOfWeek[5], .DaysOfWeek[7]
if not .CreateTask()
messagebox(.ErrorMessage)
endif not .CreateTask()
endwith
* Create a monthly task that runs at 3:00 AM on the 1st and 15th
* of every month.
loSchedule = createobject('VistaTaskScheduler')
with loSchedule
.TaskName = 'My Task Name'
.UserName = 'Your Windows UserName'
.Password = 'Your Windows Password'
.StartTime = {^2007-04-26 03:00:00}
.EXEName = 'Full path to EXE'
.EXEParameters = 'Any parameters to pass'
.ScheduleType = 3
store .T. to .DaysOfMonth[1], .DaysOfMonth[15]
.MonthsOfYear = .T. && initialize all 12 elements of array to .T.
if not .CreateTask()
messagebox(.ErrorMessage)
endif not .CreateTask()
endwith
Posts
All Comments
